Name

catch

Description

The catch keyword is used with try to handle exceptions. Sun's Java documentation defines an exception as "an event, which occurs during the execution of a program, that disrupts the normal flow of the program's instructions." This could be, for example, an error while a file is read.

Examples

  • BufferedReader reader;
    String line;
     
    void setup() {
      // Open the file from the createWriter() example
      reader = createReader("positions.txt");    
    }
     
    void draw() {
      try {
        line = reader.readLine();
      } catch (IOException e) {
        e.printStackTrace();
        line = null;
      }
      if (line == null) {
        // Stop reading because of an error or file is empty
        noLoop();  
      } else {
        String[] pieces = split(line, TAB);
        int x = int(pieces[0]);
        int y = int(pieces[1]);
        point(x, y);
      }
    }
    

Syntax

  • try {
  • tryStatements
  • } catch (exception) {
  • catchStatements
  • }

Parameters

  • tryStatementsif this code throws an exception, then the code in "catch" is run
  • exceptionthe Java exception that was thrown
  • catchStatementscode that handles the exception